ZenHAX

Free Game Research Forum | Official QuickBMS support | twitter @zenhax | SSL HTTPS://zenhax.com
It is currently Sun May 28, 2017 6:38 am

All times are UTC




Post new topic  Reply to topic  [ 3 posts ] 
Author Message
 Post subject: Various game archives
PostPosted: Mon Oct 19, 2015 2:49 pm 

Joined: Tue Sep 08, 2015 11:27 am
Posts: 62
Code:
# extracts the *.TPK archives from "Criminal Girls"
# (c) 2015-02-03 by Einstein95 of just about everywhere
# script for QuickBMS http://quickbms.aluigi.org

get FILEZ long
for i = 0 < FILEZ
    get OFFSET long
    getdstring NAME 0x1C
    savepos T
    get SIZE long
    if SIZE == 0
        get SIZE asize
    endif
    math SIZE - OFFSET
    log NAME OFFSET SIZE
    goto T
next i


Probably has been done before, just wasn't on the Zentax Wiki.
Code:
# extracts the *.far archives from "The Sims (PC)"
# (c) 2015-01-25 by Einstein95 of just about everywhere
# script for QuickBMS http://quickbms.aluigi.org

idstring FAR!byAZ
get VER long
get DIR long
goto DIR
get FILEZ long
for i = 0 < FILEZ
    get SIZE long
    get SIZEC long
    get OFFSET long
    get NAMELEN long
    getdstring NAME NAMELEN
    log NAME OFFSET SIZE
next i


DQ7 (3DS)
Code:
# extracts the *.fpt archives from "Dragon Quest 7"
# (c) 2015-01-14 by Einstein95 of just about everywhere
# script for QuickBMS http://quickbms.aluigi.org

idstring FPT0
get NULL long
get FILES long
get unk long
set FILEZ 0x20
math FILEZ * FILES
math FILEZ + 0x50 # account for the header and 0x40 gap between the table and data

for i = 0 < FILES
    getdstring NAME 0x10
    get CRC long
    get OFFSET long
    get SIZE long
    get NULL long
    math OFFSET + FILEZ
    log NAME OFFSET SIZE
next i


My first script
Code:
# extracts the *.DAT archives from "Fable" (PC, 1996)
# (c) 2013-10-10 by Einstein95 of just about everywhere
# script for QuickBMS http://quickbms.aluigi.org

idstring "ARC1"
get FILEZ int
for i = 0 < FILEZ
    getdstring NAME 0xE
    get OFFSET long
    get SIZE long
    log NAME OFFSET SIZE
next i


Manhole (DOS) BLK files
Code:
get NULL short
get FILEZ long
idstring "FLEX"
for i = 0 < FILEZ
   get OFF long
   get NULL long
   get SIZE long
   log "" OFF SIZE
next i


Gyakuten Saiban 2 (PC) LINK files
Code:
idstring "LINK"
get FILEZ long
for i = 0 < FILEZ
   getdstring NAME 0x40
   set NAME unicode NAME
   get OFFSET long
   get SIZE long
   log NAME OFFSET SIZE
next i


Satyr (PC-98) DLB install files
Code:
idstring "<< dlb file Ver1.00>>"
get NULL byte
get FILEZ short
for i = 0 < FILEZ
    getdstring NAME 0xD
    get OFF long
    get SIZE long
    log NAME OFF SIZE
next i


Metal Slug Anthology (PSP) POD files
Code:
idstring POD3
goto 0x58
get NUMFILES long
goto 0x108
get FILETBL long
goto 0x110
get NAMETBLS long
set NAMETBL NUMFILES
math NAMETBL * 0x14    # size of FILETBL
math NAMETBL + FILETBL # therefore the offset of NAMETBL
goto FILETBL
for i = 0 < NUMFILES
    get NAMEOFF long
    get SIZE long
    get OFF long
    savepos TEMP1
    math TEMP1 + 0x8
    math NAMEOFF + NAMETBL
    goto NAMEOFF
    get NAME string
    goto TEMP1
    log NAME OFF SIZE
next i


Game & Watch (DSiWare)
Code:
comtype LZ77WII
do
   get OFF long
   get SIZE long
   clog "" OFF SIZE SIZE
while OFF != 0


Applesauce Journey [あっぷるそーす JOURNEY] (PC) MLK
Code:
get FILEZ byte
for i = 0 < FILEZ
   get UNK byte
   get OFF long
   get SIZE long
   log "" OFF SIZE
next i


Ore wa Shoujo Mangaka (オレは少女漫画家) (PSP)
Code:
open FDDE "idx" 0
open FDDE "pak" 1
get FILES asize 0
math FILES / 24
for i = 0 < FILES
    get DUMMY long #crc?
    get OFFSET long
    get SIZE long
    getdstring NAME 0xC
    log NAME OFFSET SIZE 1
next i


Top
   
PostPosted: Mon Oct 19, 2015 5:28 pm 
Site Admin
User avatar

Joined: Wed Jul 30, 2014 9:32 pm
Posts: 6015
If you plan to make more of them or if you want to collect them in a thread everytime you make new ones, you can also use the Collection of tools section viewforum.php?f=17
AlphaTwentyThree made something similar on Xentax, with a thread in which he collects all his scripts.

Or the best alternative is hosting and indexing them on a website :)


Top
   
PostPosted: Tue Oct 20, 2015 5:39 am 

Joined: Tue Sep 08, 2015 11:27 am
Posts: 62
Ahh, thanks :)
If you want to move the thread that'll be cool.


Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 3 posts ] 

All times are UTC


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Powered by phpBB® Forum Software © phpBB Limited