ZenHAX

Free Game Research Forum | Official QuickBMS support | twitter @zenhax | SSL HTTPS://zenhax.com
It is currently Mon Sep 25, 2017 2:37 am

All times are UTC




Post new topic  Reply to topic  [ 5 posts ] 
Author Message
PostPosted: Mon May 29, 2017 7:53 pm 

Joined: Fri Jun 24, 2016 6:26 am
Posts: 36
Hi, I've tried to extract some audio files from this game, but without luck.
The files header is @utf, but seems those contain a AFS2 file inside of it.

Here's some samples:
Attachment:
Assets.rar [3.63 MiB]
Downloaded 29 times


Regards.


Top
   
PostPosted: Tue May 30, 2017 8:31 am 

Joined: Tue Sep 30, 2014 5:59 pm
Posts: 61
Code:
## Based On
# CRI Audio @UTF (script 0.1.3)
#   thanks to Taylor&Lion for the alignment field
# script for QuickBMS http://quickbms.aluigi.org

quickbmsver "0.7.3"

idstring "@UTF"

get FILESIZE asize 0

goto 0 0
findloc OFFSET_HEADER string "StreamAwbAfs2Header" 0 ""
if OFFSET_HEADER == ""
    cleanexit
endif

goto OFFSET_HEADER 0
findloc OFFSET_FILENAME string "CueIndex" 0 ""
if OFFSET_FILENAME == ""
    cleanexit
endif

goto OFFSET_FILENAME 0

set FILENAME_COUNT 0
get DUMMY string
for
    get FILENAME string

    if FILENAME != ""
        putarray 0 FILENAME_COUNT FILENAME
        math FILENAME_COUNT += 1
    else
        break
    endif
next

findloc OFFSET_MAIN string "AFS2" 0 ""
if OFFSET_MAIN == ""
    cleanexit
endif

goto OFFSET_MAIN 0

get HEADER long
get DUMMY long
get FILES long
get MYALIGN long
for i = 0 < FILES
    get ALIGN short
    putarray 1 i ALIGN
next i

    callfunction GET_OFFSET 1
math OFFSET = VALUE
for i = 0 < FILES
    callfunction GET_OFFSET 1
    math NEXT_OFFSET = VALUE

    getarray FILENAME 0 i
    if MYALIGN != 0
        math ALIGN = MYALIGN
    else
        getarray ALIGN 1 i
    endif

    math OFFSET x= ALIGN
    math OFFSET_FILE = OFFSET_MAIN
    math OFFSET_FILE += OFFSET
    math SIZE = NEXT_OFFSET
    math SIZE -= OFFSET
    math OFFSET = NEXT_OFFSET
    string FILENAME += ".hca"

    log FILENAME OFFSET_FILE SIZE
next i


startfunction GET_OFFSET
    if DUMMY & 0x200
        get VALUE short
    else
        get VALUE long
    endif
endfunction


Attachment:
HCA Decoder v2.zip [63.91 KiB]
Downloaded 21 times


Last edited by ponaromixxx on Tue May 30, 2017 9:21 pm, edited 1 time in total.

Top
   
PostPosted: Tue May 30, 2017 5:53 pm 

Joined: Fri Jun 24, 2016 6:26 am
Posts: 36
Thanks a lot @ponaromixxx, but the decoder doesn't work well, the audio runs so fast or maybe I'm doing something wrong.


Top
   
PostPosted: Tue May 30, 2017 9:20 pm 

Joined: Tue Sep 30, 2014 5:59 pm
Posts: 61
Cornal_Ec wrote:
Thanks a lot @ponaromixxx, but the decoder doesn't work well, the audio runs so fast or maybe I'm doing something wrong.


Replaced decoder! :D

Attachment:
HCA Decoder v2.zip [63.91 KiB]
Downloaded 36 times


Top
   
PostPosted: Wed May 31, 2017 4:11 am 

Joined: Fri Jun 24, 2016 6:26 am
Posts: 36
Good work, Thank You So Much!!!!! :)


Top
   
Display posts from previous:  Sort by  
Post new topic  Reply to topic  [ 5 posts ] 

All times are UTC


You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot post attachments in this forum

Search for:
Powered by phpBB® Forum Software © phpBB Limited